mirror of
https://github.com/Nheko-Reborn/nheko.git
synced 2024-11-22 11:00:48 +03:00
c9f1a449d8
Qt6 changed the mouse scroll wheel handling for QtQuick to a type that mimics how touch pads/screens work, which most people find feels very poor. KDE fixes this by creating a custom type which re-implements the QtWidgets handling (see https://invent.kde.org/frameworks/kirigami/-/merge_requests/415). On Matrix Nico has expressed a desire not to have to deal with compiling Kirigami for Windows and Mac, which is understandable. Linux users on the other hand almost always have kirigami available in their package repos which sidesteps that particular issue. We can search for Kirigami at build time and if present define a QML context property to allow it to be used, which should fix this issue for Linux users at least. Helps with nheko-reborn/nheko#1819 (which won't be completely resolved until this is working for Windows and Mac as well). Signed-off-by: Reilly Brogan <reilly@reillybrogan.com>
97 lines
2.9 KiB
QML
97 lines
2.9 KiB
QML
// SPDX-FileCopyrightText: Nheko Contributors
|
|
//
|
|
// SPDX-License-Identifier: GPL-3.0-or-later
|
|
|
|
import QtQuick 2.9
|
|
import QtQuick.Controls 2.5
|
|
import QtQuick.Layouts 1.3
|
|
import im.nheko 1.0
|
|
|
|
Page {
|
|
id: uploadPopup
|
|
|
|
Layout.fillWidth: true
|
|
Layout.preferredHeight: 200
|
|
clip: true
|
|
padding: Nheko.paddingMedium
|
|
visible: room && room.input.uploads.length > 0
|
|
|
|
background: Rectangle {
|
|
color: palette.base
|
|
}
|
|
contentItem: ListView {
|
|
id: uploadsList
|
|
|
|
Loader {
|
|
source: NHEKO_USE_KIRIGAMI ? "components/KirigamiWheelHandler.qml" : ""
|
|
}
|
|
|
|
anchors.horizontalCenter: parent.horizontalCenter
|
|
boundsBehavior: Flickable.StopAtBounds
|
|
model: room ? room.input.uploads : undefined
|
|
orientation: ListView.Horizontal
|
|
spacing: Nheko.paddingMedium
|
|
width: Math.min(contentWidth, parent.availableWidth)
|
|
|
|
ScrollBar.horizontal: ScrollBar {
|
|
id: scr
|
|
|
|
}
|
|
delegate: Pane {
|
|
id: pane
|
|
|
|
height: uploadPopup.availableHeight - buttons.height - (scr.visible ? scr.height : 0)
|
|
padding: Nheko.paddingSmall
|
|
width: uploadPopup.availableHeight - buttons.height
|
|
|
|
background: Rectangle {
|
|
color: palette.window
|
|
radius: Nheko.paddingMedium
|
|
}
|
|
contentItem: ColumnLayout {
|
|
Image {
|
|
property string typeStr: switch (modelData.mediaType) {
|
|
case MediaUpload.Video:
|
|
return "video-file";
|
|
case MediaUpload.Audio:
|
|
return "music";
|
|
case MediaUpload.Image:
|
|
return "image";
|
|
default:
|
|
return "zip";
|
|
}
|
|
|
|
Layout.fillHeight: true
|
|
Layout.fillWidth: true
|
|
fillMode: Image.PreserveAspectFit
|
|
mipmap: true
|
|
smooth: true
|
|
source: (modelData.thumbnail != "") ? modelData.thumbnail : ("image://colorimage/:/icons/icons/ui/" + typeStr + ".svg?" + palette.buttonText)
|
|
sourceSize.height: pane.availableHeight - namefield.height
|
|
sourceSize.width: pane.availableWidth
|
|
}
|
|
MatrixTextField {
|
|
id: namefield
|
|
|
|
Layout.fillWidth: true
|
|
text: modelData.filename
|
|
|
|
onTextEdited: modelData.filename = text
|
|
}
|
|
}
|
|
}
|
|
}
|
|
footer: DialogButtonBox {
|
|
id: buttons
|
|
|
|
standardButtons: DialogButtonBox.Cancel
|
|
|
|
onAccepted: room.input.acceptUploads()
|
|
onRejected: room.input.declineUploads()
|
|
|
|
Button {
|
|
DialogButtonBox.buttonRole: DialogButtonBox.AcceptRole
|
|
text: qsTr("Upload %n file(s)", "", (room ? room.input.uploads.length : 0))
|
|
}
|
|
}
|
|
}
|